/*
 * Tuxánci 2 - A first person shooter
 * Copyright (C) 2025-2026  Connor Thomson
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

struct model_uniforms {
    float4x4 mvp;
    float4x4 model;
    float4x4 light_view_projection;
    float3   camera_position;
    float    shadow_normal_offset;
};

[[vk::binding(0, 1)]]
ConstantBuffer<model_uniforms> uniforms : register(b0, space1);

struct VSInput {
    float3 position : POSITION0;
    float3 normal   : NORMAL0;
};

struct VSOutput {
    float4 position              : SV_Position;
    float3 normal                : TEXCOORD0;
    float3 world_position        : TEXCOORD1;
    float3 camera_position       : TEXCOORD2;
    float4 light_space_position  : TEXCOORD3;
};

VSOutput main(VSInput input) {
    VSOutput output;
    float4 world_position       = mul(uniforms.model, float4(input.position, 1.0));
    float3 world_normal         = normalize(mul((float3x3)uniforms.model, input.normal));
    output.position             = mul(uniforms.mvp, float4(input.position, 1.0));
    output.normal               = world_normal;
    output.world_position       = world_position.xyz;
    output.camera_position      = uniforms.camera_position;
    float3 offset_position      = world_position.xyz + world_normal * uniforms.shadow_normal_offset;
    output.light_space_position = mul(uniforms.light_view_projection, float4(offset_position, 1.0));
    return output;
}